$!
$! Command procedure to invoke EDR reblocking routine
$!
$ set on
$ on control_y then goto END
$ on warning then goto ERRMSG
$ on error then goto ERRMSG
$!
$ wo :== write sys$output
$ ask :== inquire
$ clr :== @sys$system:clear.com
$!
$ set def VOYAGER:[voyager.command]
$!
$ START:
$ clr
$ wo "     VOYAGER EDR RENAMING PROCEDURE"
$ wo ""
$ wo "     This procedure strips the leading character for the filename"
$ wo ""
$ wo "Expected input format:"
$ wo ""
$ wo "   DEVICE:[DIRECTORY PATH]"
$ wo ""
$ wo "      ex. 1)  DKA400:[VOYAGER.V2.EDR.Y89]"
$ wo "      ex. 2)  VOYAGER:[VOYAGER.DATA.EDR]"
$ wo ""
$ ask path  "Input EDR path"
$ name_position = f$locate(":", path)
$ if name_position .eq. f$length(path)
$ then
$  write sys$output "Device name missing from path, ex., DKA400:"
$  exit
$ endif
$! Get device name
$ dev = f$extract(0,'name_position'+1,path)
$! write sys$output "Device = ",dev
$ name_position2 = f$locate("]", path)
$ if name_position2 .eq. f$length(path)
$ then
$  write sys$output "Directory missing from path, ex., [VOYAGER.DATA.EDR]"
$  exit
$ endif
$ ask outpath "Output EDR path ''path'"
$ if outpath .eqs. "" then outpath = path
$! write sys$output "outpath = ", outpath
$ length= name_position2 - name_position + 1
$! Get directory name
$ filepath = f$extract('name_position'+1,'length',path) 
$! write sys$output "Directory = ", filepath
$ if dev .eqs. "DKA400:" .or dev .eqs. "CDROM:"  
$ then
$!
$ CDMOUNT:
$  wo ""
$  wo "CDROM mount required."
$  ask ans "Is CDROM media in drive (y/n)?"
$  if ans .eqs. "n" .or. ans .eqs. "N" 
$  then
$   wo ""
$   ask ans "Continue (y/n)?"
$   if ans .eqs. "n" .or. ans .eqs. "N" then goto END
$   clr
$   goto CDMOUNT
$  endif
$  wo "Mounting CDROM..."
$  wo ""
$  mount/over=id/media=cdrom/undef=(fixed:none:512) 'dev'
$  wo ""
$ endif
$! END CDMOUNT
$ ext = "EDR"
$ directory/col=1/ver=1/notrail/nohead/out=edrlist.dat 'path'*.'ext'
$ open infile edrlist.dat
$ cnt = 0
$ loop:
$ read/end=end_loop infile rec
$ cnt = cnt + 1
$! write sys$output "rec = ", rec
$ dir_position1 = f$locate("]",rec)
$ dir_position2 = f$locate(";",rec)
$! write sys$output "dir_position1 = ", dir_position1 
$! write sys$output "dir_position2 = ", dir_position2
$ length = dir_position2 - dir_position1 - 5
$! Get EDR name w/o extension
$ filename = f$extract('dir_position1'+1,'length',rec)' + ".edr"
$ newname = f$extract('dir_position1'+2,'length'-1,rec)' + ".edr"
$! write sys$output "Renaming EDR ", filename, " to ", newname
$ filename = path + filename
$ newname = outpath + newname
$ set verify
$ rename 'filename' 'newname'
$ set noverify
$!
$! repeat for next EDR
$ goto loop
$ end_loop: 
$ close infile
$ delete/noconfrim edrlist.dat;*
$! Dismount CDROM
$ if dev .eqs. "DKA400:" then dismount DKA400:
$ if dev .eqs. "CDROM:" then dismount CDROM: 
$!
$ END:
$ wo ""
$ exit
$!
$ ERRMSG:
$ wo ""
$ wo "RUNTIME ERROR ENCOUNTERED.  PROCEDURE TERMINATED."
$ wo ""
$ set noon
$ delete/noconfrim edrlist.dat;*
$! Dismount CDROM
$ if dev .eqs. "DKA400:" then dismount DKA400:
$ if dev .eqs. "CDROM:" then dismount CDROM:
$ exit