$!
$! EDR_DUMP.COM
$!
$! EDR header file dump command procedure
$!
$! Modified to create file and print.  SBK 03/28/95
$! Modified to submit batch job.  SBK 07/25/95
$!
$ SET ON
$ ON CONTROL_Y THEN GOTO END
$ ON WARNING THEN GOTO ERRMSG
$ ON ERROR THEN GOTO ERRMSG
$ CLR :== @SYS$SYSTEM:CLEAR.COM
$ WO :== WRITE SYS$OUTPUT
$ ASK :== INQUIRE
$ CLR
$ WO " "
$ WO "     VOYAGER EDR HEADER DUMP PROCEDURE"
$ WO " "
$ WO " "
$ START:
$ WO " "
$ WO "IMPORTANT NOTE!
$ WO " "
$ WO "EDR's must be reblocked BEFORE using this procedure."
$ WO "To verify reblocking, select ""Read EDR header block""
$ WO "from the main menu."
$ WO " "
$!
$ LIST:
$ wo ""
$ ask dev  "Input device name ( VOYAGER )"
$ if dev .eqs. "" then dev = "VOYAGER"
$!
$ PATH:
$ ask path "Input directory path ( VOYAGER.DATA.EDR )"
$ if path .eqs. "" then path = "VOYAGER.DATA.EDR"
$!
$ NAME:
$ ASK EDRNAME "Enter EDR input file name"
$ IF EDRNAME .EQS. "" 
$ THEN
$  WO ""
$  WO "INVALID ENTRY.  TRY AGAIN."
$  WO ""
$  GOTO NAME
$ ENDIF
$!
$ EDRIN = dev + ":[" + path + "]" + EDRNAME + ".DAT"
$ WO ""
$ WO "Selected file:  ",EDRIN
$ WO ""
$ ASK ANS "Dump file (Y/N)?"
$ IF ANS .EQS. "N" .OR. ANS .EQS. "n" THEN GOTO LIST
$!
$! CREATE BATCH COMMAND PROCEDURE
$!
$ OPEN/WRITE BATCH SYS$LOGIN:EDRDUMP.COM
$ DUMPFILE = "SYS$LOGIN:"'EDRNAME'".DMP"
$ WRITE BATCH "$ ASSIGN ''DUMPFILE' SYS$OUTPUT"
$ WRITE BATCH "$ RUN VOYAGER:[VOYAGER.EXECUTABLE]EDRREAD.EXE"
$ WRITE BATCH "''EDRIN'"
$ WRITE BATCH "$ DEASSIGN SYS$OUTPUT"
$ WRITE BATCH "$ PRINT/QUE=''MONGO_DEF' ''DUMPFILE'"
$ WRITE BATCH "$ EXIT"
$ CLOSE BATCH
$!
$ WO " "
$ WO "SUBMITTING EDR DUMP BATCH JOB..."
$ WO " "
$ SUBMIT/NOPRINT/NOTIFY/LOG=SYS$LOGIN SYS$LOGIN:EDRDUMP.COM
$ EXIT
$!
$ ERRMSG:
$ WO " "
$ WO "RUNTIME ERROR ENCOUNTERED.  PROCEDURE TERMINATED."
$ WO " "
$!
$ END:
$ EXIT