;docformat='rst'
;+
;  Converts one or more rows from the orbit table into orbit_info structure(s).
;
; :Author:
;    Chris Jeppesen
;
;-
;+
; :Params:
;   row: required, in, type=structure
;     result of query_database on the orbit table
;
; :Returns:
;   an array of orbit_info structures, one for each row being passed
;-
;+
; :Examples:
;     last_orbits = sql_to_orbit_info(row)
;-
function sql_to_orbit_info,row
  if n_elements(row) gt 1 then begin
    result=sql_to_orbit_info(row[0])
    for i=1,n_elements(row)-1 do begin
      result=[result,sql_to_orbit_info(row[i])]
    end
    return,result
  end else begin
    orbit_info=get_orbit_info_structure()
    orbit_info.start_time=row.startTime
    orbit_info.stop_time=row.endTime
    orbit_info.sunrise=row.sunriseTime
    orbit_info.sunset=row.sunsetTime
    orbit_info.rise150=row.rise150
    orbit_info.set150=row.set150
    orbit_info.n_term=row.nTerm
    orbit_info.s_term=row.sTerm
    orbit_info.orbit_number=row.orbitNum
    orbit_info.mission_day=row.missionDay
    orbit_info.n_look=[row.nLookX,row.nLookY,row.nLookZ]
    orbit_info.s_look=[row.sLookX,row.sLookY,row.sLookZ]
    orbit_info.rejected = 0
    return,orbit_info
  end
end