;docformat='rst'
;+
;    Generate SQL from orbit info structs
;
; :Author:
;    Chris Jeppesen, Bill Barrett
;
;-
;+
;
; :Params:
;   orbit_info : in, required, type=struct
;     One or more orbit_info structs to be used to generate SQL
;
; :Returns:
;   The SQL generated from the orbit info structs
;
; :Examples:
;     sql = orbit_info_to_sql(orbit_info)
;-
function orbit_info_to_sql, orbit_info
  if n_elements(orbit_info) gt 1 then begin
    sql=orbit_info_to_sql(orbit_info[0])
    for i=1,n_elements(orbit_info)-1 do begin
      sql=[sql,orbit_info_to_sql(orbit_info[i])]
    endfor
    return, sql
  endif else begin
    sql='insert into AIM_CIPS_SCIENCE.Orbits(orbitNum, missionDay, startTime, endTime) values (' + $
      string(orbit_info.orbit_number)+',' + $
      string(orbit_info.mission_day)+','  + $
      string(long64(orbit_info.start_time))+"," + $
      string(long64(orbit_info.stop_time)) +")"
    sql=[sql,'insert into AIM_CIPS_SCIENCE.Sofie(orbitNum, sunriseTime,sunsetTime,rise150,set150,' + $
      'nLookX,nLookY,nLookZ,nTerm,sTerm,sLookX,sLookY,sLookZ) values (' + $
      string(orbit_info.orbit_number)+',' + $
      string(long64(orbit_info.sunrise))+',' + $
      string(long64(orbit_info.sunset))+','+ $
      string(long64(orbit_info.rise150))+',' + $
      string(long64(orbit_info.set150))+',' + $
      string(orbit_info.n_Look[0],format='(%"%10.7f")')+',' + $
      string(orbit_info.n_Look[1],format='(%"%10.7f")')+',' + $
      string(orbit_info.n_Look[2],format='(%"%10.7f")')+',' + $
      string(long64(orbit_info.rise150))+',' + $
      string(long64(orbit_info.set150))+',' + $
      string(orbit_info.s_Look[0],format='(%"%10.7f")')+',' + $
      string(orbit_info.s_Look[1],format='(%"%10.7f")')+',' + $
      string(orbit_info.s_Look[2],format='(%"%10.7f")')+')']
    return,sql
  endelse
end