;+
;  $Id: get_hdr_info.pro,v 1.2 2007/03/14 14:20:33 ddelapp Exp $
;
;  $Source: /usr/lib/cvsroot/twins-idl/lib/util/get_hdr_info.pro,v $
;  $Revision: 1.2 $
;  $Date: 2007/03/14 14:20:33 $
;
; NAME:
;   GET_HDR_INFO
;
; PURPOSE: given data that matches requested ftpe create structure of 
;          header information and return
;
;
; INPUTS:
;   ftype:      subset of data that matches requested ftype
;   bdata:      raw byte data
;
; RETURN VALUE:
;   hdr:        header structure
;
;
;  Author:  Dorothea DeLapp LANL 2007
;  Modification $Author: ddelapp $
;-
; 
; function get_hdr_info
function get_hdr_info,ftype,bdata

hdr=replicate({ $
;
; use those values as index to unpack the rest of the wrapper variables
;
; Wrapper
c_pt :long64(0), $
c_gr:long64(0), $
st_b:0L, $
fr_sz:0L, $
f_gr:0L, $
;
; primary header
;
versionid :0, $
typeid :0, $
header_flag :0, $
istid :0, $
pktid :0, $
sub_ctr :0, $
group_flag :0, $
scount :0, $
pkt_len :0, $
;
; secondary header
c_pt_sh :long64(0), $
f_pt_sh :0L, $
telem :0, $

            Dataidx : 0L },n_elements(ftype))
;
; unpack variables
;
   hdr.c_pt = ishft(long64(bdata[ftype-16]),24) + $
              ishft(long64(bdata[ftype-15]),16) + $
               ishft(long64(bdata[ftype-14]),8) + $
                ishft(long64(bdata[ftype-13]),0)
   hdr.c_gr = ishft(long64(bdata[ftype-12]),24) + $
              ishft(long64(bdata[ftype-11]),16) + $
               ishft(long64(bdata[ftype-10]),8) + $
                ishft(long64(bdata[ftype-9]),0)
   hdr.st_b = ishft(long(bdata[ftype-8]),24) + $
              ishft(long(bdata[ftype-7]),16) + $
               ishft(long(bdata[ftype-6]),8) + $
                ishft(long(bdata[ftype-5]),0)
   hdr.fr_sz = ishft(long(bdata[ftype-4]),24) + $
              ishft(long(bdata[ftype-3]),16) + $
               ishft(long(bdata[ftype-2]),8) + $
                ishft(long(bdata[ftype-1]),0)
   hdr.f_gr = ishft(long(bdata[ftype+4]),24) + $
              ishft(long(bdata[ftype+5]),16) + $
               ishft(long(bdata[ftype+6]),8) + $
                ishft(long(bdata[ftype+7]),0)
   hdr.versionid = ishft(bdata[ftype+8] AND 224,-5)
   hdr.typeid = ishft(bdata[ftype+8] AND 16,-4)
   hdr.header_flag = ishft(bdata[ftype+8] AND 8,-3)
   hdr.istid = ishft(bdata[ftype+8] AND 6,-1)
   hdr.pktid = ishft(bdata[ftype+9] AND 224,-5)
   hdr.sub_ctr = ishft(bdata[ftype+9] AND 31,0)
   hdr.group_flag = ishft(bdata[ftype+10] AND 192,-6)
   hdr.scount = ishft(bdata[ftype+10] AND 63,8) + $
                 ishft(bdata[ftype+11],0)

   hdr.pkt_len = ishft(long(bdata[ftype+12]),8) + $
                   ishft(long(bdata[ftype+13]),0)
   hdr.c_pt_sh = ishft(long64(bdata[ftype+14]),24) + $
                 ishft(long64(bdata[ftype+15]),16) + $
                  ishft(long64(bdata[ftype+16]),8) + $
                   ishft(long64(bdata[ftype+17]),0)
   hdr.f_pt_sh = ishft( ishft(long(bdata[ftype+18]),8) + $
                 ishft(long(bdata[ftype+19]),0), -4)
   hdr.telem = ishft(bdata[ftype+19] AND 15,0)
   hdr.dataidx=ftype+20
;
; return hdr info
;
   return,hdr
end