SUBROUTINE CR2PRI(GAMMA,SCF,TIME,BAD)
C
C USING 48 SECOND CR-2 EDR RECORD, PRODUCE 48 SECOND BLOCK OF 
C 1.92 SEC AVERAGES FROM PRIMARY MAG DETAIL (0.12 SEC) DATA POINTS.
C
C ORIGINAL SOURCE WRITTEN BY SANDY KRAMER  03/22/96
C
      CHARACTER RECTYPE*4,TELFMT*4,FLTID*4
C
      INTEGER*2 TIME(6),EDRTIME(6),LAUNCH(6),
     &          WORD30(2),WORD31(2),WORD32(2)
C
      INTEGER*4 IB192(25)
C
      REAL*4 SCF(3,400),GAMMA(3,400),FMOD(400),DEL(400),LAM(400),
     &       B192(3,25),DEL192(25),LAM192(25),FMOD192(25),
     &       FMAG192(25),RMS192(3,25),X192(25),Y192(25),Z192(25)
C
      REAL*4 HDR(32),DATA(341)
C
      INCLUDE 'UNPACK.INC'
C
      EQUIVALENCE (SUMOUT(1),HDR(1)),    (SUMOUT(33),DATA(1))
C
      EQUIVALENCE (HDR(30),WORD30(1)),   (HDR(31),WORD31(1))
C
      EQUIVALENCE (DATA(67),FMAG192(1)), (DATA(92),FMOD192(1)),
     &            (DATA(117),DEL192(1)), (DATA(142),LAM192(1)),
     &            (DATA(242),RMS192(1,1)),(DATA(317),IB192(1))
C
C COMPUTE 25 1.92 SECOND AVERAGES FOR ONE 48 SECOND PERIOD
C
      DO J=1,25
C
       I = (J-1)*16 + 1
C
C COMPUTE DETAIL FIELD MODULUS AND ANGLES
C
       CALL ANGLES(GAMMA(1,I),16,FMOD(I),DEL(I),LAM(I),BAD)
C
C COMPUTE 1.92 SECOND FIELD COMPONENTS, MAGNITUDE AND COMPONENT RMS
C
       CALL STATS(GAMMA(1,I),FMOD(I),16,B192(1,J),
     &            FMAG192(J),RMS192(1,J),IB192(J),BAD)
C
      END DO
C
      WORD30(1) = 400
      WORD30(2) = 200
      WORD31(1) = 400
      WORD31(2) = 200
C 
C COMPUTE 48 SECOND AVERAGE OF THE SPACECRAFT FIELD
C
      CALL CR2SCF(SCF(1,1),TIME,BAD)
C
C COMPUTE 9.6 SECOND AVERAGES AND 48 SECOND AVERAGES
C
      CALL BIGAVE(B192,TIME,BAD)
C
      RETURN
      END